﻿Shader "Nostalgia/Tiles/Default"
{
	Properties
	{
		_MainTex ("Tiles Texture", 2D) = "white" {}
		_Color ("Tint", Color) = (1,1,1,1)

		_StencilComp("Comparison", Float) = 0
		_Stencil("Ref", Range(0.0, 255.0)) = 0
		_StencilWriteMask("Write Mask",Range(0.0, 255.0)) = 255
		_StencilReadMask("Read Mask",Range(0.0, 255.0)) = 255
		_StencilPass("Pass",Float) = 0
		_StencilFail("Fail",Float) = 0
		_StencilZFail("ZFail",Float) = 0
		_ColorMask("Color Mask",Float) = 15
		_Cutoff("Alpha Cutoff", Range(0.0, 1.0)) = 0.5

		[MaterialToggle] PixelSnap ("Pixel snap", Float) = 0
	}

	SubShader
	{
		Tags
		{ 
			"Queue"="Transparent" 
			"IgnoreProjector"="True" 
			"RenderType"="Transparent" 
			"PreviewType"="Plane"
			"CanUseSpriteAtlas"="True"
		}

		Cull Off
		Lighting Off
		ZWrite Off
		Blend One OneMinusSrcAlpha
		ColorMask [_ColorMask]

		Stencil
		{
			Ref [_Stencil]
			ReadMask [_StencilReadMask]
			WriteMask [_StencilWriteMask]
			Comp [_StencilComp]
			Pass [_StencilPass]
			Fail [_StencilFail]
			ZFail [_StencilZFail]
		}

		Pass
		{
		CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#pragma shader_feature _ALPHATEST_ON

			#pragma multi_compile_local _ PIXELSNAP_ON
			#include "UnityCG.cginc"
			#include "./TileCG.cginc"
			
			struct appdata_t
			{
				float4 vertex   : POSITION;
				float4 color    : COLOR;
				float2 texcoord : TEXCOORD0;
				float4 animation : TEXCOORD1;	// Animation Frame Num, Scroll Width, Frame rate, 0
			};

			struct v2f
			{
				float4 vertex   : SV_POSITION;
				fixed4 color    : COLOR;
				half2 texcoord  : TEXCOORD0;
			};
			
			sampler2D _MainTex;
			fixed4 _Color;
			half _Cutoff;

			v2f vert(appdata_t IN)
			{
				v2f OUT;
				OUT.vertex = ObjectToClipPos(IN.vertex);
				OUT.texcoord = AnimateUV(IN.texcoord, IN.animation);
				OUT.color = IN.color * _Color;
				#ifdef PIXELSNAP_ON
				OUT.vertex = UnityPixelSnap (OUT.vertex);
				#endif

				return OUT;
			}

			fixed4 frag(v2f IN) : SV_Target
			{
				fixed4 c = tex2D(_MainTex, IN.texcoord) * IN.color;

#if defined(_ALPHATEST_ON)
				clip(c.a - _Cutoff);
#endif

				c.rgb *= c.a;
				return c;
			}
		ENDCG
		}
	}

	Fallback "Sprites/Default"
	CustomEditor "NostalgiaEditor.TilesDefaultShaderGUI"
}
